Nested Properties

[mooman_fl]

Ok... here is a new one concerning properties on a usercontrol. I would like to have the nifty nested properties on my control (i.e. Size, Location, DockPadding, etc.)

 

Anyone have a clue as to how this is done?

[Heiko]

Just to make it clear to dumbos (as I am) ;)

 

What do you mean with "nested"?

 

Like "grouped" in the Properties view at designtime?

 

Or "Hierarchical" at runtime as in

 

myObject.Layout.Location = New System.Drawing.Point(42,42)

 

?

[mooman_fl]

I am talking like in the propertygrid at designtime. All the properties that contain a plus next to them.

[divil]

I think you have to specify a TypeConverter attribute pointing to ExpandableObjectConverter on the class which your property has as its value.

[mooman_fl]

I have read a few things that suggested this. However looking at the MSDN help, I am embarrassed to admit, helped very little. It was way over my head. Not to mention that everything I have seen on this is in VC++ (or maybe it was C#). Does anyone know of any information out there that takes this subject from the ground up geared towards a VB user?

[divil]

Here's a quick example I whipped up which does the trick:

 

Imports System.ComponentModel

Public Class ClassWithProperty
   Private _Expandy As ExpandyClass

   Public Sub New()
       _Expandy = New ExpandyClass()
   End Sub

   Public Property Expandy() As ExpandyClass
       Get
           Return _Expandy
       End Get
       Set(ByVal Value As ExpandyClass)
           _Expandy = Value
       End Set
   End Property
End Class

<TypeConverter(GetType(ExpandableObjectConverter))> _
Public Class ExpandyClass
   Private _Variable1, _Variable2 As Integer

   Public Property Variable1() As Integer
       Get
           Return _Variable1
       End Get
       Set(ByVal Value As Integer)
           _Variable1 = Value
       End Set
   End Property

   Public Property Variable2() As Integer
       Get
           Return _Variable2
       End Get
       Set(ByVal Value As Integer)
           _Variable2 = Value
       End Set
   End Property

End Class

[mooman_fl]

LOL... your killing me man ;) You just whipped this up... *choke**gasp**goggle*:eek: Have you ever noticed how some people make seem so easy what makes the rest of us lose hair and sleep over?

 

Thanks!!! I will examine this thoroughly. Once again you have saved the day. :)

[divil]

It's only easy because I had to do this before. Believe me, I had a similar headache then!

[mooman_fl]

Hmmm... tried implementing your method of doing this in my project. I got the expandable class made (Padding), I declared it in the declarations section, then in new tired to instantiate it.

 

I got an error that says: Value of type 'ToolScroll.ToolPanel.Padding' cannot be converted to '1-dimensional array of ToolScroll.ToolPanel.Padding'.

 

Any idea what this means and why I am getting it? I really haven't done anything different that I can see from your example.

[divil]

You've put a () on your private declaration in the class I expect.

[mooman_fl]

That seems to have indeed been the problem.

 

I find it interesting that it is wrong to do it in your Private declaration, yet it is necessary and automatically added for you when you instantiate.

[Heiko]

A declaration with () means that you are not declaring a single variable but an array.

 

Instantiating with () means you are calling the parameterless constructor.

 

These are two entirely different operations.

[mooman_fl]

Thanks Heiko, that makes sense. :)

[dnagroove]

Divil, I would like to thank you too.

 

This example has actually saved me various forms of headaches.

 

Thanks again.

[wyrd]

I was passing by and figured I'd take a look at this interesting topic to see how it was done... I understand the example, and find it interesting actually, heh. Except, well, I got a n00b question..

 

Why is <TypeConverter(GetType(ExpandableObjectConverter))> needed?

[Volte]

The TypeConverterAttribute (attributes being the < > tags that precede

some classes) tells VB what TypeConverter to use

in the designer. In this case, it converts it to a format that the property

window knows how to interpret and respond to accordingly. You

could write your own TypeConverter as well, if you wanted.

[mooman_fl]

Hmmm... I would be interested in seeing how that is done if anyone cares to show an example.

[divil]

TypeConverters are classes applied to other classes that enable conversion to and from that class type. A Size structure, for example, has a typeconverter that allows you to enter "100, 200" as a string in the propertygrid and it'll convert it to a size with X being 100 and Y being 200.

 

The ExpandableObjectConverter class is extremely simple and does little more than tell the propertygrid that this object has properties that should be delved in to.

[wyrd]

Ahhh. Good stuff. I think it's time for me to do some reading up on Attributes and Reflection. :)

[Lexus]

This threat is very old, but, i have one little question about this. Is it possible to give the .ExpandyClass a name in the propertygrid? Now it displays Applicationname.ExpandyClass. I can't find this property?

Giving Categories a name is not a problem, just the expanding item...